xref: /illumos-gate/usr/src/lib/libm/i386/src/ilogb.s (revision ddc0e0b5)
1/*
2 * CDDL HEADER START
3 *
4 * The contents of this file are subject to the terms of the
5 * Common Development and Distribution License (the "License").
6 * You may not use this file except in compliance with the License.
7 *
8 * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
9 * or http://www.opensolaris.org/os/licensing.
10 * See the License for the specific language governing permissions
11 * and limitations under the License.
12 *
13 * When distributing Covered Code, include this CDDL HEADER in each
14 * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
15 * If applicable, add the following below this CDDL HEADER, with the
16 * fields enclosed by brackets "[]" replaced with your own identifying
17 * information: Portions Copyright [yyyy] [name of copyright owner]
18 *
19 * CDDL HEADER END
20 */
21/*
22 * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
23 */
24/*
25 * Copyright 2006 Sun Microsystems, Inc.  All rights reserved.
26 * Use is subject to license terms.
27 */
28
29        .file "ilogb.s"
30
31#include "libm.h"
32LIBM_ANSI_PRAGMA_WEAK(ilogb,function)
33#include "xpg6.h"
34
35	.data
36	.align	8
37two52:	.long	0x0,0x43300000	/ 2**52
38
39	ENTRY(ilogb)
40	movl	8(%esp),%eax		/ eax <-- hi_32(x)
41	andl	$0x7fffffff,%eax	/ eax <-- hi_32(abs(x))
42	testl	$0x7ff00000,%eax	/ is bexp(x) 0?
43	jz	.bexp_0 		/ jump if x is 0 or subnormal
44					/ biased exponent is non-zero
45	cmpl	$0x7ff00000,%eax	/ is bexp(x) 0x7ff?
46	jae	.bexp_all_1		/ jump if x is NaN or Inf
47	shrl	$20,%eax		/ eax <-- bexp(x)
48	subl	$1023,%eax		/ unbias exponent by 1023
49	ret
50
51.bexp_all_1:
52	movl	$0x7fffffff,%eax	/ x is NaN or inf, so return 0x7fffffff
53	jmp	0f
54
55.bexp_0:
56	orl	4(%esp),%eax		/ test whether x is 0
57	jnz	.ilogb_subnorm
58	movl	$0x80000001,%eax	/ x is +/-0, so return 0x80000001
590:
60	PIC_SETUP(0)
61	PIC_G_LOAD(movzwl,__xpg6,ecx)
62	PIC_WRAPUP
63	andl	$_C99SUSv3_ilogb_0InfNaN_raises_invalid,%ecx
64	cmpl	$0,%ecx
65	je	1f
66	fldz
67	fdivp	%st,%st(0)		/ raise invalid as per SUSv3
681:
69	ret
70
71.ilogb_subnorm:				/ subnormal input
72	fldl	4(%esp)			/ push x
73	PIC_SETUP(1)
74	fmull	PIC_L(two52)		/ x*2**52
75	PIC_WRAPUP
76	subl	$8,%esp			/ set up storage area
77	fstpl	(%esp)			/ store x*2**52 in storage are
78	movl	$0x7ff00000,%eax
79	andl	4(%esp),%eax
80	shrl	$20,%eax		/ extract exponent of x*2**52
81	subl	$1075,%eax		/ unbias it by 1075 (= 1023 + 52)
82	addl	$8,%esp
83	ret
84	.align	4
85	SET_SIZE(ilogb)
86