xref: /illumos-gate/usr/src/cmd/dtrace/demo/io/iothrough.d (revision 7c478bd9)
1 /*
2  * CDDL HEADER START
3  *
4  * The contents of this file are subject to the terms of the
5  * Common Development and Distribution License, Version 1.0 only
6  * (the "License").  You may not use this file except in compliance
7  * with the License.
8  *
9  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
10  * or http://www.opensolaris.org/os/licensing.
11  * See the License for the specific language governing permissions
12  * and limitations under the License.
13  *
14  * When distributing Covered Code, include this CDDL HEADER in each
15  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
16  * If applicable, add the following below this CDDL HEADER, with the
17  * fields enclosed by brackets "[]" replaced with your own identifying
18  * information: Portions Copyright [yyyy] [name of copyright owner]
19  *
20  * CDDL HEADER END
21  */
22 /*
23  * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
24  * Use is subject to license terms.
25  */
26 
27 #pragma D option quiet
28 
29 io:::start
30 {
31 	start[args[0]->b_edev, args[0]->b_blkno] = timestamp;
32 }
33 
34 io:::done
35 /start[args[0]->b_edev, args[0]->b_blkno]/
36 {
37 	/*
38 	 * We want to get an idea of our throughput to this device in KB/sec.
39 	 * What we have, however, is nanoseconds and bytes.  That is we want
40 	 * to calculate:
41 	 *
42 	 *                        bytes / 1024
43 	 *                  ------------------------
44 	 *                  nanoseconds / 1000000000
45 	 *
46 	 * But we can't calculate this using integer arithmetic without losing
47 	 * precision (the denomenator, for one, is between 0 and 1 for nearly
48 	 * all I/Os).  So we restate the fraction, and cancel:
49 	 *
50 	 *     bytes      1000000000         bytes        976562
51 	 *   --------- * -------------  =  --------- * -------------
52 	 *      1024      nanoseconds          1        nanoseconds
53 	 *
54 	 * This is easy to calculate using integer arithmetic; this is what
55 	 * we do below.
56 	 */
57 	this->elapsed = timestamp - start[args[0]->b_edev, args[0]->b_blkno];
58 	@[args[1]->dev_statname, args[1]->dev_pathname] =
59 	    quantize((args[0]->b_bcount * 976562) / this->elapsed);
60 	start[args[0]->b_edev, args[0]->b_blkno] = 0;
61 }
62 
63 END
64 {
65 	printa("  %s (%s)\n%@d\n", @);
66 }
67