xref: /illumos-gate/usr/src/lib/libc/i386/gen/wschr.s (revision 9a70fc3b)
1/*
2 * CDDL HEADER START
3 *
4 * The contents of this file are subject to the terms of the
5 * Common Development and Distribution License (the "License").
6 * You may not use this file except in compliance with the License.
7 *
8 * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
9 * or http://www.opensolaris.org/os/licensing.
10 * See the License for the specific language governing permissions
11 * and limitations under the License.
12 *
13 * When distributing Covered Code, include this CDDL HEADER in each
14 * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
15 * If applicable, add the following below this CDDL HEADER, with the
16 * fields enclosed by brackets "[]" replaced with your own identifying
17 * information: Portions Copyright [yyyy] [name of copyright owner]
18 *
19 * CDDL HEADER END
20 */
21
22/*
23 * Copyright 2008 Sun Microsystems, Inc.  All rights reserved.
24 * Use is subject to license terms.
25 */
26
27	.file	"wschr.s"
28
29/
30/ Wide character wcschr() implementation
31/
32/ Algorithm based on Solaris 2.6 gen/strchr.s implementation
33/
34
35#include "SYS.h"
36
37	ANSI_PRAGMA_WEAK(wcschr,function)
38	ANSI_PRAGMA_WEAK(wschr,function)
39
40	.align	8		/ accounts for .loop alignment and prolog
41
42	ENTRY(wcschr)
43	movl	4(%esp),%eax	/ %eax = string address
44	movl	8(%esp),%ecx	/ %ecx = wchar sought
45.loop:
46	movl	(%eax),%edx	/ %edx = wchar of string
47	cmpl	%ecx,%edx	/ find it?
48	je	.found		/ yes
49	testl	%edx,%edx	/ is it null?
50	je	.notfound
51
52	movl	4(%eax),%edx	/ %edx = wchar of string
53	cmpl	%ecx,%edx	/ find it?
54	je	.found1		/ yes
55	testl	%edx,%edx	/ is it null?
56	je	.notfound
57
58	movl	8(%eax),%edx	/ %edx = wchar of string
59	cmpl	%ecx,%edx	/ find it?
60	je	.found2		/ yes
61	testl	%edx,%edx	/ is it null?
62	je	.notfound
63
64	movl	12(%eax),%edx	/ %edx = wchar of string
65	cmpl	%ecx,%edx	/ find it?
66	je	.found3		/ yes
67	addl	$16,%eax
68	testl	%edx,%edx	/ is it null?
69	jne	.loop
70
71.notfound:
72	xorl	%eax,%eax	/ %eax = NULL
73	ret
74
75.found3:
76	addl	$12,%eax
77	ret
78.found2:
79	addl	$8,%eax
80	ret
81.found1:
82	addl	$4,%eax
83.found:
84	ret
85	SET_SIZE(wcschr)
86
87	ENTRY(wschr)
88	_prologue_
89	movl	_esp_(8),%eax
90	movl	_esp_(4),%edx
91	pushl	%eax
92	pushl	%edx
93	call	_fref_(wcschr)
94	addl	$8,%esp
95	_epilogue_
96	ret
97	SET_SIZE(wschr)
98